satdump/android/SatDump/build.gradle

apply plugin: 'com.android.application'

android {
    compileSdkVersion 28
    buildToolsVersion "30.0.2"
    ndkVersion "23.0.7599858"

    defaultConfig {
        applicationId "com.altillimity.satdump"
        minSdkVersion 28
        targetSdkVersion 28
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        externalNativeBuild {
            cmake {
                cppFlags ""
            }
        }
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    externalNativeBuild {
        cmake {
            path "src/main/cpp/CMakeLists.txt"
        }
    }

    sourceSets {
        main {
            // We're using SDLActivity from SDL sources, not copying that to our source tree
            java.srcDirs += ['src/main/cpp/deps/SDL/android-project/app/src/main/java']
            // Instead of copying data files from the native project, we just add its data
            // as another asset directory
            assets.srcDirs += ['assets']
        }
    }

    lintOptions {
          abortOnError false
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation 'androidx.appcompat:appcompat:1.0.2'
    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'androidx.test:runner:1.1.1'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.1.1'
}

task deleteTempAssets (type: Delete) {
    delete 'assets'
}

task copyPipelines(type: Copy) {
    description = 'Copy pipelines...'
    from '../../pipelines'
    into 'assets/pipelines'
    include('**/*')
}

task copyResources(type: Copy) {
    description = 'Copy resources...'
    from '../../resources'
    into 'assets/resources'
    include('**/*')
}

task copyFont(type: Copy) {
    description = 'Copy font...'
    from '../../Roboto-Medium.ttf'
    into 'assets/'
    include('*')
}

copyPipelines.dependsOn deleteTempAssets
copyResources.dependsOn deleteTempAssets
copyFont.dependsOn deleteTempAssets

preBuild.dependsOn copyPipelines
preBuild.dependsOn copyResources
preBuild.dependsOn copyFont