mirror of
https://github.com/curl/curl
synced 2026-08-25 12:32:35 -04:00
dea00a6d73
Their output is nearly identical to curl's implementations. Minor differences: it goes to stdout (curl: stderr), marks cache variables, but doesn't mark 'advanced' ones. Also: - indent curl's output to match CMake's. - replace single quotes with double to match CMake output. - alpha-sort target properties to match CMake. - alpha-sort config types to match CMake. - tested OK with cmake-4.4.20260811-g567ed0e and 4.4.20260812-g760e4fb. Refs:f723293c7fhttps://gitlab.kitware.com/cmake/cmake/-/merge_requests/11834 https://gitlab.kitware.com/cmake/cmake/-/work_items/27513 https://cmake.org/cmake/help/git-master/command/cmake_language.html#command:cmake_language Follow-up to855acb3bb0#17701 Follow-up tof58342ae21#15562 Follow-up tocd51bb503a#14439 Closes #22566
93 lines
3.7 KiB
CMake
93 lines
3.7 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# File containing various utilities
|
|
|
|
# Return number of arguments that evaluate to true
|
|
function(curl_count_true _output_count_var)
|
|
set(_list_len 0)
|
|
foreach(_option_var IN LISTS ARGN)
|
|
if(${_option_var})
|
|
math(EXPR _list_len "${_list_len} + 1")
|
|
endif()
|
|
endforeach()
|
|
set(${_output_count_var} ${_list_len} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
# Dump all defined variables with their values
|
|
function(curl_dumpvars)
|
|
message("::group::CMake Variable Dump")
|
|
if(CMAKE_VERSION VERSION_GREATER_EQUAL 4.5)
|
|
cmake_language(PRINT_VARIABLES ALL)
|
|
else()
|
|
get_cmake_property(_vars VARIABLES)
|
|
foreach(_var IN ITEMS ${_vars})
|
|
get_property(_var_type CACHE ${_var} PROPERTY TYPE)
|
|
get_property(_var_advanced CACHE ${_var} PROPERTY ADVANCED)
|
|
if(_var_type)
|
|
set(_var_type ":${_var_type}")
|
|
endif()
|
|
if(_var_advanced)
|
|
set(_var_advanced " [adv]")
|
|
endif()
|
|
message(" ${_var}${_var_type}${_var_advanced} = \"${${_var}}\"")
|
|
endforeach()
|
|
endif()
|
|
message("::endgroup::")
|
|
endfunction()
|
|
|
|
# Dump all target properties
|
|
function(curl_dumptargetprops _target)
|
|
if(CMAKE_VERSION VERSION_GREATER_EQUAL 4.5)
|
|
cmake_language(PRINT_PROPERTIES TARGETS "${_target}" ALL)
|
|
elseif(CMAKE_VERSION VERSION_GREATER_EQUAL 3.19 AND TARGET "${_target}")
|
|
execute_process(COMMAND "${CMAKE_COMMAND}" "--help-property-list" OUTPUT_VARIABLE _cmake_property_list)
|
|
string(REPLACE "\n" ";" _cmake_property_list "${_cmake_property_list}")
|
|
list(REMOVE_DUPLICATES _cmake_property_list)
|
|
list(REMOVE_ITEM _cmake_property_list "")
|
|
list(APPEND _cmake_property_list "INTERFACE_LIBCURL_PC_MODULES")
|
|
get_target_property(_target_imported ${_target} IMPORTED)
|
|
if(NOT _target_imported)
|
|
list(REMOVE_ITEM _cmake_property_list "LOCATION" "LOCATION_<CONFIG>" "MACOSX_PACKAGE_LOCATION" "VS_DEPLOYMENT_LOCATION")
|
|
endif()
|
|
list(SORT _cmake_property_list)
|
|
foreach(_prop IN LISTS _cmake_property_list)
|
|
if(_prop MATCHES "<CONFIG>")
|
|
foreach(_config IN ITEMS "DEBUG" "MINSIZEREL" "RELEASE" "RELWITHDEBINFO")
|
|
string(REPLACE "<CONFIG>" "${_config}" _propconfig "${_prop}")
|
|
get_property(_is_set TARGET "${_target}" PROPERTY "${_propconfig}" SET)
|
|
if(_is_set)
|
|
get_target_property(_val "${_target}" "${_propconfig}")
|
|
message(" ${_target}.${_propconfig} = \"${_val}\"")
|
|
endif()
|
|
endforeach()
|
|
else()
|
|
get_property(_is_set TARGET "${_target}" PROPERTY "${_prop}" SET)
|
|
if(_is_set)
|
|
get_target_property(_val "${_target}" "${_prop}")
|
|
message(" ${_target}.${_prop} = \"${_val}\"")
|
|
endif()
|
|
endif()
|
|
endforeach()
|
|
endif()
|
|
endfunction()
|