mirror of
https://github.com/yasm/yasm
synced 2026-08-26 22:26:05 -04:00
a5d91fba6a
enabled with --enable-python (defaults to auto-detect). Thanks to some magic in python-yasm/Makefile.inc and setup.py, this actually plays nicely with automake distcheck. * m4/pythonhead.m4: Script to find Python.h. * m4/Makefile.inc: Include it in distfiles. * configure.ac: Add --enable-python option and Python and Pyrex detection. * tools/Makefile.inc: Pull tools/python-yasm/Makefile.inc into build. * python-yasm/Makefile.inc: Add automake build magic for extension. * setup.py: Likewise. svn path=/trunk/yasm/; revision=1456
24 lines
912 B
Text
24 lines
912 B
Text
dnl a macro to check for ability to create python extensions
|
|
dnl AM_CHECK_PYTHON_HEADERS([ACTION-IF-POSSIBLE], [ACTION-IF-NOT-POSSIBLE])
|
|
dnl function also defines PYTHON_INCLUDES
|
|
AC_DEFUN([AM_CHECK_PYTHON_HEADERS],
|
|
[AC_REQUIRE([AM_PATH_PYTHON])
|
|
AC_MSG_CHECKING(for headers required to compile python extensions)
|
|
dnl deduce PYTHON_INCLUDES
|
|
py_prefix=`$PYTHON -c "import sys; print sys.prefix"`
|
|
py_exec_prefix=`$PYTHON -c "import sys; print sys.exec_prefix"`
|
|
PYTHON_INCLUDES="-I${py_prefix}/include/python${PYTHON_VERSION}"
|
|
if test "$py_prefix" != "$py_exec_prefix"; then
|
|
PYTHON_INCLUDES="$PYTHON_INCLUDES -I${py_exec_prefix}/include/python${PYTHON_VERSION}"
|
|
fi
|
|
AC_SUBST(PYTHON_INCLUDES)
|
|
dnl check if the headers exist:
|
|
save_CPPFLAGS="$CPPFLAGS"
|
|
CPPFLAGS="$CPPFLAGS $PYTHON_INCLUDES"
|
|
AC_TRY_CPP([#include <Python.h>],dnl
|
|
[AC_MSG_RESULT(found)
|
|
$1],dnl
|
|
[AC_MSG_RESULT(not found)
|
|
$2])
|
|
CPPFLAGS="$save_CPPFLAGS"
|
|
])
|